breed [ bacteria bacterium ]
breed [ cells cell ]
breed [ macrophages macrophage ]
breed [ neutrophils neutrophil ]
bacteria-own [ energy target-patch amt-consumed ]
macrophages-own [ consumed radius speed capacity]
neutrophils-own [ consumed radius speed capacity]
patches-own [ glucose chemical cell-present tissue-damage immune-chemicals targeted death-chance]

globals [
  seconds-per-frame
  macrophage-sense-distance ; How far away macrophages can sense chemical
  bacteria-size ; Bacteria size
  macrophage-radius ; Macrophage size
  neutrophil-radius ; Neutrophil size
  macrophage-motility
  neutrophil-motility
  cell-radius ; Body cell size
  reinforcements-coming ; Flag to indicate macrophage reinforcements are coming
  reinforcement-timer ; Timer to implement reinforcement delay
  reinforcement-count ; Number of macrophages per reinforcement
  glucose-diffusion-rate ; Diffusion rate of glucose in patches
  global-scale ; Global scale in micometers
  bacteria-reproduce-cost
  bacteria-reproduce-spread
  neutrophil-delay ; Initial delay for neutrophil arrival at infection site
  max-glucose-concentration ; Glucose concentration in the blood
  max-neutrophil-time
  max-neutrophil-count
  recruitment-delay
  chemical-dissipation-rate
  max-immune-chemical
]

to setup-globals
  set recruitment-delay 1440
  set seconds-per-frame 10 ; each time step is 10 seconds
  set global-scale 0.28 ; micrometers per pixel
  set bacteria-size 1 * global-scale
  set macrophage-sense-distance 4
  set macrophage-radius 10.6 * global-scale ;
  set neutrophil-radius 4.2 * global-scale ;
  set neutrophil-motility 0.45 * global-scale * seconds-per-frame ; speed of neutrophil movement
  set macrophage-motility 0.15 * global-scale * seconds-per-frame ; speed of macrophage movement
  set cell-radius 2 * global-scale
  set reinforcements-coming true
  set reinforcement-timer recruitment-delay
  set reinforcement-count 1
  set glucose-diffusion-rate 0.4
  set bacteria-reproduce-cost 1
  set neutrophil-delay 60
  set max-glucose-concentration 100 ; 100 mg/dL
  set max-neutrophil-time 14400 * seconds-per-frame ; 4 hours (in seconds)
  set chemical-dissipation-rate 6
  set max-immune-chemical 3000
end

to setup
  clear-all

  setup-globals

  create-bacteria initial-bacteria-count
  [
    initialize-bacteria
  ]

  ;create-cells cell-count
  ;[
  ;  set shape "circle 2"
  ;  set color red
  ;  set size cell-radius * 1.3
  ;  setxy random-xcor random-ycor
  ;]

   ask patches [
    set glucose 1
    ;set cell-present false
    set tissue-damage 0
    set immune-chemicals 0
  ]

  ask patches [set-color]

  reset-ticks
end


; ************************************************************************ TO GO ****************************************************************************************
to go
  ; Stop if reached total # ticks or all the intruders are destroyed
  if (not any? turtles) or (not any? bacteria)  [ stop ]

  ask patches [set targeted false]

  ; Diffuse glucose
  diffuse glucose glucose-diffusion-rate

  ; Diffuse chemical
  diffuse chemical 0.2

  ; Diffuse immune chemicals
  diffuse immune-chemicals 0.2

  check-reinforcements

  if ticks = max-neutrophil-time
    [set max-neutrophil-count (count neutrophils)]

  ; If bacteria are present, simulation continues. Initiate neutrophil response.
  ; We're assuming that neutrophils are not intially present at t=0 when wounding occurs and bacteria are introduced
  if (ticks = neutrophil-delay) [
    create-neutrophils 1
   [ initialize-neutrophil ]

    ifelse ticks < max-neutrophil-time
    [set neutrophil-delay floor (neutrophil-delay + neutrophil-delay * (1 / (count neutrophils)))]
    [set neutrophil-delay floor (neutrophil-delay + neutrophil-delay * ((count neutrophils) / max-neutrophil-count))]
  ]

  ; Bacteria consume energy and release chemicals,
  ; then decide whether to move or divide
  ask bacteria [
    react-to-immune-chemicals
    consume-energy
    decide-action
  ]

  ; Neutrophils move toward bacteria, consume them, and then
  ; call for reinforcements if they detect enough intruders nearby
  ask neutrophils [
    move-to-bacteria
    release-immune-chemicals ; this must be before phagocytosis
    phagocytose
    ;signal-reinforcements
  ]

  ;create-macrophages initial-macrophage-count
  ;[ initialize-macrophage ]

  ; Macrophages move toward bacteria, consume them,
  ; can release chemicals to kill bacteria, and then
  ; call for reinforcements if they detect enough intruders nearby
  ; (macrophages calling for reinforcements is currently not active)
  ask macrophages [
    move-to-bacteria
    release-immune-chemicals ; this must be before phagocytosis
    phagocytose
    ;signal-reinforcements
  ]

  ; Each patch of the ECM receives more glucose from the blood
  ; possibly gets tissue damage,
  ; and then sets its color based on the patch-view option
  ask patches [
    increase-glucose
    increase-tissue-damage
    set-color
  ]

  tick

  ifelse display-consumed
  [ ask macrophages [ set label consumed] ]
  [ ask macrophages [ set label ""] ]
end




; *********************************************************************** BACTERIA FUNCTIONS *****************************************************************************************************
to initialize-bacteria
  set shape  "bug"
  set color green
  set size bacteria-size
  set energy random-float bacteria-reproduce-cost
  setxy random-xcor random-ycor
end

; chemicals released by immune cells can kill bacteria
to react-to-immune-chemicals
    if (random-float 1) < death-chance ; arbitrary but the more chemicals, the more chance the number will be over the threshold
    [ die ]
end

; Consume energy and leave behind chemical
; Cells in the body can recognize parts of bacteria and respond with inflammatory signals
; Normally non-immune cells would also respond by releasing signaling chemicals
; but for our model we skip straight to immune cells responding
to consume-energy
  ; Consume energy from local glucose
  set amt-consumed avg-bacteria-consumption-rate * 0.9 + random-float (avg-bacteria-consumption-rate * 0.2)
  if glucose < amt-consumed
  [ set amt-consumed glucose ]
  set energy (energy + amt-consumed)
  set glucose (glucose - amt-consumed)

  ; Leave behind a chemical that macrophages & neutrophils can sense
  ask patches in-radius 4 [
    set chemical chemical + 1
  ]
end

to decide-action
  ; If the bacterium has enough energy to reproduce, it does that. Otherwise it moves.
  ifelse energy > bacteria-reproduce-cost
  [ reproduce ]
  [ move-to-glucose ]
end

; cell division of bacteria
to reproduce
  ; As long as the bacterium has enough energy, create a new bacterium
  ; Doubling time = 60min, so max is once per 1hr tick
  if energy > bacteria-reproduce-cost [
    set energy (energy - bacteria-reproduce-cost)
    hatch 1 [ rt random-float 360 fd random 0.5]
  ]
end

; bacteria want glucose (or other sugars/nutrients) as energy sources
to move-to-glucose
  if(glucose < bacteria-reproduce-cost)
  [
    ; Move to the closest patch with a sufficient amount of glucose
    set target-patch max-one-of (patches in-radius 2) [glucose]
    if target-patch != nobody
    [
      face target-patch
      fd 1 + random-float 1
    ]
  ]
end

; *********************************************************************** IMMUNE CELL FUNCTIONS *********************************************************************************************
to initialize-neutrophil
  set radius neutrophil-radius
  set shape "circle 2"
  set color red
  set size neutrophil-radius * 2
  set consumed 0
  set speed neutrophil-motility
  set capacity 10
  setxy random-xcor random-ycor
end

to initialize-macrophage
  set radius macrophage-radius
  set shape "circle 2"
  set color white
  set size macrophage-radius * 2
  set consumed 0
  set speed macrophage-motility
  set capacity 100
  setxy random-xcor random-ycor
end

; immune cells are attracted to infection so they can fight it
to move-to-bacteria
    ; Move to the patch with the strongest chemical
  let sensed-patches (patches in-radius macrophage-sense-distance) with [not targeted]
    let potential-targets (sensed-patches with-max [chemical])

    ; If more than half of our sensed patches have the same maximum chemical,
    ; Just pick a slightly deferred course and keep moving
    ifelse count potential-targets < (count sensed-patches) / 2
    [
      let target (one-of potential-targets)
      face target
    ask target [set targeted true]
    ]
    [
      rt random 30
      lt random 30
    ]
    fd (speed * 0.8) + (random-float (speed * 0.2))
end

; some immune cells can fight bacteria by releasing chemicals that kill the bacteria
; Note for model implementation: releasing chemicals must be before phagocytosing otherwise it will never be activated
; because all bacteria within range will be gone
to release-immune-chemicals
let nearby-patches (patches in-radius (radius * 0.7))
  if (count bacteria-on nearby-patches) > 10
  [ ask nearby-patches
    [
      set immune-chemicals min list max-immune-chemical (immune-chemicals + 1000)
      set death-chance ((immune-chemicals / max-immune-chemical) ^ 10 ) * immune-chemical-toxicity
    ]
  ]

end

; some immune cells like neutrophils and macrophages can "eat" bacteria and destroy them
to phagocytose
  let nearby-patches (patches in-radius radius)
  ask nearby-patches [set chemical 0]
  ; Eat the intruders and keep track of how many we've eaten
  if consumed < capacity
  [
    set consumed consumed + (count bacteria-on nearby-patches)
    ask bacteria-on nearby-patches [ die ]
  ]
  set consumed max list 0 (consumed - phagocytosis-rate / 6)
end

; should new immune cells be recruited?
to signal-reinforcements
  ; Set the global reinforcement indicator which will be fulfilled
  ; after a delay
  let nearby-patches (patches in-radius (radius * 2))
  if (count bacteria-on nearby-patches) > 1
  [ set reinforcements-coming true ]
end

; immune cells recruit other immune cells to help fight the infection
to check-reinforcements
  if reinforcements-coming
  [
    ; Count down the timer
    set reinforcement-timer reinforcement-timer - 1;

    ; If the timer is at zero, add the number of
    ; reinforcements and then reset the timer
    if reinforcement-timer <= 0
    [
      create-macrophages reinforcement-count
      [ initialize-macrophage ]
      set reinforcement-timer recruitment-delay
    ]
  ]
end

; *********************************************************************** PATCH FUNCTIONS *********************************************************************************************

to set-color
  ; Choose to view the amount of chemical or
  if patch-view = "chemical"
  [ set pcolor scale-color cyan chemical 0 1000 ]
  if patch-view = "glucose"
  [ set pcolor scale-color blue glucose 0 3 ]
  if patch-view = "immune-chemicals"
  [ set pcolor scale-color red immune-chemicals 0 (max-immune-chemical) ]
end

; replenish glucose and make chemicals from bacteria dissipate
to increase-glucose
  ; Increase the ECM glucose levels
  if glucose <= 1 [
      set glucose (glucose + (random-float max-glucose-replenishment-rate))
    if chemical > 0
      [set chemical max (list 0 (chemical - chemical-dissipation-rate))]
    ]
end

; over time, the immune response to the bacteria can cause tissue damage
to increase-tissue-damage
  ; increase tissue-damage
  if ((chemical ^ (0.02) + immune-chemicals ^ (0.2)) > 5) ; this calculation is arbitrary
  [set tissue-damage (tissue-damage + 10)]
end
@#$#@#$#@
GRAPHICS-WINDOW
543
15
1221
694
-1
-1
10.0
1
10
1
1
1
0
1
1
1
-33
33
-33
33
1
1
1
ticks
30.0

BUTTON
95
38
270
88
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
288
38
468
88
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
0

PLOT
15
299
541
692
Plot
NIL
NIL
0.0
10.0
0.0
10.0
true
true
"" ""
PENS
"bacteria" 1.0 0 -14439633 true "" "plot count bacteria"
"total glucose" 1.0 0 -13345367 true "" ";plot sum [glucose] of patches"
"macrophage recruitment" 1.0 0 -3026479 true "" "if reinforcement-timer = 1\n[\n  plot-pen-up\n  plotxy ticks 0 \n  plot-pen-down\n  plotxy ticks plot-y-max \n]"
"total tissue damage" 1.0 0 -2674135 true "" "plot sum [tissue-damage] of patches / 10000"

SLIDER
286
112
536
145
initial-bacteria-count
initial-bacteria-count
1
5000
2490.0
1
1
NIL
HORIZONTAL

SLIDER
17
150
273
183
max-glucose-replenishment-rate
max-glucose-replenishment-rate
0
0.1
0.04
0.01
1
NIL
HORIZONTAL

CHOOSER
15
242
162
287
patch-view
patch-view
"glucose" "chemical" "immune-chemicals"
2

MONITOR
366
189
533
238
Number of macrophages
count macrophages
0
1
12

SWITCH
168
245
322
278
display-consumed
display-consumed
1
1
-1000

MONITOR
332
244
536
289
Macrophage Recruitment Countdown
reinforcement-timer
0
1
11

SLIDER
30
112
270
145
avg-bacteria-consumption-rate
avg-bacteria-consumption-rate
0
0.005
0.0024
0.0001
1
NIL
HORIZONTAL

SLIDER
290
154
535
187
immune-chemical-toxicity
immune-chemical-toxicity
0
1
0.1
0.01
1
NIL
HORIZONTAL

SLIDER
20
197
271
230
phagocytosis-rate
phagocytosis-rate
0
1
0.12
0.01
1
NIL
HORIZONTAL

@#$#@#$#@
## WHAT IS IT?

In this project, cells of the innate (non-specific) immune system respond to a bacterial infection in a shallow, acute skin wound. The user can change rates in the model to compare the time for all the bacteria to be removed (bacterial clearance) in a healthy patient compared to a diabetic patient. Diabetic patients are at an increased risk of long-lasting bacterial infections because they have increased glucose sugar levels in their bloodstream and their immune cells are less effective at fighting infection.

## HOW IT WORKS

Glucose is replenished from the blood stream at a constant rate. If bacteria have accumulated enough energy, they reproduce. Else the bacteria move towards the highest concentration of glucose, and consume it to gain more energy. A bacteria leaves a trail of chemical as it moves. 

A neutrophil, the first responder to an infection, then appears at the scene, recruiting other neutrophils to join in the fight. The neutrophils follow the chemical trail from the bacteria. Neutrophils leave a trail of immune chemicals which kill bacteria and gobble the bacteria up by phagocytosis if they get close enough.

Later, macrophages appear at the scene which also release immune chemicals and gobble up bacteria. The macrophages are more effective at killing bacteria than neutrophils, but are slower to respond to the infection.

Over time, the build-up of chemicals from the bacteria and immune cells damages the tissue.

## HOW TO USE IT

Click the SETUP button to set up the infected wound. Click the GO button to start the simulation. The bacteria are green, the neutrophils are black circles with a red border, and the macrophages are larger black circles with a white border. Use the PATCH-VIEW dropdown to view glucose levels, bacterial chemicals, or immune chemicals. Glucose is shown in blue, while chemicals are shown in white. 

Before pressing SETUP, the model can be adjusted using a number of sliders:
-If you want to change the number of bacteria initially introduced into the wound, use the INITIAL-BACTERIA-COUNT slider before pressing SETUP. 
-Similarly, the rate at which glucose is replenished from the bloodstream can be adjusted using the MAX-GLUCOSE-REPLENISHMENT-RATE slider. 
-The AVG-BACTERIA-CONSUMPTION-RATE slider controls how fast bacteria can consume glucose to gain more energy. 
-The IMMUNE-CHEMICAL-TOXICITY slider controls how effective the immune chemicals are at killing the bacteria, and the PHAGOCYTOSIS-RATE slider controls how fast the immune cells can gobble up bacteria.

## THINGS TO NOTICE

Notice that as the bacteria reproduce, the concentration of the chemical they leave behind quickly increases. The immune system then responds after a short delay. With the PATCH-VIEW = CHEMICAL, you can see that the neutrophils and macrophages leave behind a trail of blue where they have depleted the white bacterial chemical and killed the neighboring bacteria. With PATCH-VIEW = IMMUNE-CHEMICALS, you can see that the neutrophils and macrophages leave behind a trail of their own chemicals seen as white or red.

As the simulation runs, watch the MACROPHAGE RECRUITMENT COUNTDOWN for how long until the first macrophage appears.

In the plot, although bacteria number (green line) decreases over time, tissue damage (red line) increases. When all bacteria are gone, the simulation stops.

## THINGS TO TRY

Try increasing the number of initial bacteria in the wound using the INITIAL-BACTERIA-COUNT slider. How does this change the time it takes for the immune cells to remove all the bacteria?

In diabetes, patients often have increased glucose levels in their blood. Try increasing the MAX-GLUCOSE-REPLENISHMENT-RATE slider to model how this affects the time required for the immune system to clear the bacterial infection. What does this tell you about how long healing takes for someone with diabetes compared to a healthy person?

Diabetic patients also have immune systems which are less effective at fighting bacterial infections. Try decreasing the PHAGOCYTOSIS-RATE slider or decreasing the IMMUNE-CHEMICAL-TOXICITY slider to model how this affects the time required for the immune system to clear the bacterial infection. What does this tell you about how long healing takes for someone with diabetes compared to a healthy person?

## EXTENDING THE MODEL

Try modifying the macrophage functions to include both M1 (proinflammatory) and M2 (proresolving) macrophage cell populations. M1 macropahges should have increased movement towards bacteria (function: move-to-bacteria) and increased phagocytosis of bacteria (function: phagocytose). The release of immune chemicals by M1s to kill bacteria (function: release-immune-chemicals) should increase tissue damage (function: increase-tissue-damage). However, M2 macrophages should have decreased movement toward bacteria and decreased phagocytosis of bacteria. They should release different immune chemicals which decrease tissue damage and inflammation and increase wound healing.

Add complexity to the model by adding innate immunity's complement system. These new protein turtles should move toward bacteria and recruit the neutrophil immune cells rather than a chemical released from the bacteria themselves. The immune chemicals released by neutrophils and macrophages should then recruit more immune cells rather than the current countdown timer implementation. 

## NETLOGO FEATURES

The built-in diffuse primitive lets us diffuse the glucose, bacteria chemicals, and immune chemicals easily without complicated code.

The built-in primitive die removes bacteria.

The built-in primitive patches-in-radius allows bacteria and immune cells to sense the characteristics of neighboring patches.

## CREDITS AND REFERENCES

Infections in patients with diabetes mellitus: A review of pathogenesis:
https://www.ncbi.nlm.nih.gov/pmc/articles/PMC3354930/

Neutrophil function and metabolism in individuals with diabetes mellitus: http://www.scielo.br/scielo.php?script=sci_arttext&pid=S0100-879X2007000800003&lng=en&nrm=iso&tlng=en
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.0.2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="consumption-rate-sensitivity" repetitions="1" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <exitCondition>count bacteria = 0</exitCondition>
    <metric>count bacteria</metric>
    <enumeratedValueSet variable="display-consumed">
      <value value="false"/>
    </enumeratedValueSet>
    <steppedValueSet variable="avg-bacteria-consumption-rate" first="0.002" step="5.0E-4" last="0.005"/>
    <enumeratedValueSet variable="patch-view">
      <value value="&quot;immune-chemicals&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-bacteria-count">
      <value value="2500"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="max-glucose-replenishment-rate">
      <value value="0.05"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="immune-chemical-toxicity">
      <value value="0.5"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="bacteria-count-sensitivity" repetitions="1" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <metric>count bacteria</metric>
    <enumeratedValueSet variable="display-consumed">
      <value value="false"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="avg-bacteria-consumption-rate">
      <value value="0.0025"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="patch-view">
      <value value="&quot;immune-chemicals&quot;"/>
    </enumeratedValueSet>
    <steppedValueSet variable="initial-bacteria-count" first="1000" step="500" last="5000"/>
    <enumeratedValueSet variable="max-glucose-replenishment-rate">
      <value value="0.05"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="immune-chemical-toxicity">
      <value value="0.5"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="glucose-replenishment-sensitivity" repetitions="1" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <metric>count bacteria</metric>
    <enumeratedValueSet variable="display-consumed">
      <value value="false"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="avg-bacteria-consumption-rate">
      <value value="0.0025"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="patch-view">
      <value value="&quot;immune-chemicals&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-bacteria-count">
      <value value="2500"/>
    </enumeratedValueSet>
    <steppedValueSet variable="max-glucose-replenishment-rate" first="0.01" step="0.01" last="0.09"/>
    <enumeratedValueSet variable="immune-chemical-toxicity">
      <value value="0.5"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="immune-chemical-sensitivity" repetitions="1" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <metric>count bacteria</metric>
    <enumeratedValueSet variable="display-consumed">
      <value value="false"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="avg-bacteria-consumption-rate">
      <value value="0.0025"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="patch-view">
      <value value="&quot;immune-chemicals&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-bacteria-count">
      <value value="2500"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="max-glucose-replenishment-rate">
      <value value="0.05"/>
    </enumeratedValueSet>
    <steppedValueSet variable="immune-chemical-toxicity" first="0.1" step="0.1" last="0.9"/>
  </experiment>
  <experiment name="phagocytosis-rate-sensitivity" repetitions="1" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <metric>count bacteria</metric>
    <enumeratedValueSet variable="display-consumed">
      <value value="false"/>
    </enumeratedValueSet>
    <steppedValueSet variable="phagocytosis-rate" first="0" step="0.1" last="1"/>
    <enumeratedValueSet variable="avg-bacteria-consumption-rate">
      <value value="0.0025"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="patch-view">
      <value value="&quot;immune-chemicals&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-bacteria-count">
      <value value="2500"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="max-glucose-replenishment-rate">
      <value value="0.05"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="immune-chemical-toxicity">
      <value value="0.1"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
0
@#$#@#$#@